***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 23, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PDZ15B-AU A K
.param
+vc0 = 9.296e-11	 vc1 = 2.285e-11   	 vc2 = 1.082e0		 vc3 = 3.583e-11	  vc4 = 1.083e-1
+tc1 = 1.051e-2		 tc2 = 6.421e-3		 tc3 = 1.094e-2		 tc4 = 1.201e-2 
.func irexp(v) {(vc0)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc1*v**vc2+vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 4.484e-16	   n = 1.004e0		  rs = 1.571e-1		ikf = 1.507e-1
+ibv = 5e-3		 nbv = 0.8		  bv = 15
***** capacitance parameter *****
+cjo = 9.057e-11	   m = 3.211e-1		  vj = 5.520e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.152		 xti = 3
+trs1 = 1.042e-5	trs2 = -1.057e-6		
+tbv1 = 7.138e-4	tbv2 = 1.955e-7		 tikf = 5.9e-3
.ends PDZ15B-AU
*$
